UnityのシェーダーにRampテクスチャで陰を作る方法

float3 lightDir = normalize(_WorldSpaceLightPos0.xyz); //シーンのディレクショナルライト方向を取得
half d = dot(i.normal, lightDir); //ライトと法線の内積から陰のかかり方を計算
half3 ramp = tex2D(_Ramp, float2(d,d)).rgb; //Rampテクスチャからサンプリング

Shader "CAGraphicsAcademy/Toon"
{
	Properties
	{
		_MainTex("Base (RGB)", 2D) = "white" {}
		_Ramp("Toon Ramp (RGB)", 2D) = "gray" {}
		_ShadeLevel("Shade Level", Range(0, 1)) = 0
	}

	SubShader
	{
		Pass
		{
			Tags { "RenderType" = "Opaque" }
			LOD 100

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			struct appdata
			{
				float4 vertex   : POSITION;
				float3 normal   : NORMAL;
				float2 uv       : TEXCOORD0;
			};

			struct v2f
			{
				float4 vertex   : SV_POSITION;
				float3 normal   : NORMAL;
				float2 uv       : TEXCOORD0;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _Ramp;
			float _ShadeLevel;

			v2f vert(appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex); //頂点をMVP行列変換
				o.normal = UnityObjectToWorldNormal(v.normal); //各頂点が持つ法線（オブジェクト座標系）をワールド座標系に変換
				o.uv = TRANSFORM_TEX(v.uv, _MainTex); //テクスチャスケールとオフセットを加味
				return o;
			};

			fixed4 frag(v2f i) : SV_Target
			{
				float3 lightDir = normalize(_WorldSpaceLightPos0.xyz); //シーンのディレクショナルライト方向を取得

				half d = dot(i.normal, lightDir)*0.5 + _ShadeLevel; //ライトと法線の内積から陰のかかり方を計算
				half3 ramp = tex2D(_Ramp, float2(d,d)).rgb; //Rampテクスチャからサンプリング

				half4 c = tex2D(_MainTex, i.uv); //メインテクスチャからサンプリング
				c.rgb *= _LightColor0.rgb * ramp; //ライトのカラーを乗算
				return c;
			}
			ENDCG
		}
	}
}